begintownscript;

variables;
short bmessage,rctx,rcty,pcs,booms;
string custom_m;

body;

beginstate INIT_STATE;

	set_char_status(0,0,(get_char_status(0,0) * -1),1,0);
	force_view_center(47,47);
	force_instant_terrain_redraw();
	pause(10);
	reset_dialog();
	if(get_flag(99,0) == 1){
		add_dialog_str(0,"...will you die here?",0);
		add_dialog_str(1,"Probably.  But do these things really have time to sink in?  Learning about Malachai and your family...  Did you have enough time to let it sink in?",0);
		add_dialog_str(2,"No, not really.  But that's always been how it was.  You had to outrun the authorities when Chika was killed...  You learned to adjust for mom's death all too quickly.",0);
		add_dialog_str(3,"Boot Camp, it wasn't friendly to you.  Hate, ambivalence, and then enjoyment...  All of these things sequentially were unhealthy.  But you survived, right?  You're still you.  No, I'm still me.",0);
		add_dialog_str(4,"Maybe you should sit back and reflect on your beloved.  But you have a job to do.  These nephils...  This is your chance.  This is the mystical goal.  Free everything.  And then, maybe, you can contemplate your departed in silence...",0);
		add_dialog_str(5,"That works, right?  You're still with me, Chika, right?  Is my ambition really so mad?",0);
	}
	if(get_flag(99,0) == 2){
		add_dialog_str(0,"...furballs.  Damned furballs.",0);
		add_dialog_str(1,"How the hell did things turn out this way?  Why are you here?  No, why am I here?  What massive competence or incompetence created this quasi-drama of a stereotypically plagued, stereotypically off-kilter soldier boy?",0);
		add_dialog_str(2,"Maybe Malachai was right.  Maybe your drama is worthwhile.",0);
		add_dialog_str(3,"...no.  No!  That's bollocks!  That man was trapped in nothing but knightly stereotypes.  That's not true.  Your tale is the same as everyone else's because of what's weighing you down.",0);
		add_dialog_str(4,"Those parents...  That tender girl you knew so well...  Forget them.  To hell with them!  Knights so tied up with their parents aren't even human, they're scribes!  Damned scribes!  Merits of their messages be damned, it isn't for you.",0);
		add_dialog_str(5,"Screw this mad ambition of working for the rich men and awards.  Your ambition is for madness.",0);
	}

	bmessage = run_dialog(1);

	if(party_size() > 1){
		set_flag(60,0,(party_size()));
		split_off_one_char(20,18,0,0);
	}
	else{
		relocate_character(0,20,18);
	}
	force_view_center(20,18);
	force_instant_terrain_redraw();

	reset_dialog();
	add_dialog_str(0,"You wake up.",0);
	add_dialog_str(1,"Perhaps you were resisting, or maybe the blindfolds were inconvenient.  But still...  You're not that messed up, what with your having fallen unconscious.",0);
	if(get_flag(60,0) > 2){
		add_dialog_str(2,"But you're the only one here.  Where are your friends?  Are they okay?  You can't see any of them.  These cells are designed well like that.",0);
	}
	if(get_flag(60,0) == 2){
		clear_buffer();
		append_string("But you're the only one here.  Where is ");
		pcs = 1;
		while(char_ok(pcs) == FALSE){
			pcs = (pcs + 1);
		}
		append_char_name(pcs);
		append_string("?  You can't see your comrade from where you are now.  These cells are designed well like that.");
		get_buffer_text(custom_m);
		add_dialog_str(2,custom_m,0);
	}
	if(get_flag(60,0) == 1 && get_flag(99,0) == 1){
		add_dialog_str(2,"So here you are.  What are you going to do to protect people?  What can you do to save them?  What can you do to save yourself?",0);
	}
	if(get_flag(60,0) == 1 && get_flag(99,0) == 2){
		add_dialog_str(2,"So here you are.  Those furballs...  Did they honestly think they could keep you down?",0);
	}
	add_dialog_str(3,"You check your equipment.  Surprising as it may be, all of it is there.  You're actually still armed.  That seems like a bizarre mistake for them to make with you.",0);
	add_dialog_str(4,"Well...  Without a way to open the gate, even with your gear, it looks like your only option is to wait for a while.",0);
	bmessage = run_dialog(1);

	block_entry(1);

break;

beginstate EXIT_STATE;
break;

beginstate START_STATE;

	if(get_flag(61,0) == 20){

		clear_buffer();
		append_string("_Hey!  Psst!  ");
		append_char_name(0);
		append_string(", how's it going?_");
		get_buffer_text(custom_m);
		message_dialog(custom_m,"...no.  It can't be.  Anthony?");

		activate_hidden_group(1);
		relocate_character(9,19,16);
		if(char_loc_x(0) == 19){
			relocate_character(0,20,char_loc_y(0));
		}
		force_instant_terrain_redraw();
		pause(8);

		reset_dialog();
		add_dialog_str(0,"_So...  You finally saw what I saw ahead of time, I bet...  Listen, I'm sorry for keeping you in the dark like this.  It's just that they were already mobilizing.  I didn't want to be spotted._",0);
		if(get_flag(60,0) == 2){
			add_dialog_str(1,"_But I'm here, right?  So, I mean, that's good, right?  Although...  Where's your partner?_",0);
			add_dialog_choice(0,"What?");
		}
		if(get_flag(60,0) > 2){
			add_dialog_str(1,"_But I'm here, right?  So, I mean, that's good, right?  Although...  Where's the rest of your group?_",0);
			add_dialog_choice(0,"What?");
		}
		if(get_flag(60,0) == 1){
			add_dialog_str(1,"_But I'm here, right?  So, I mean, that's good, right?  I mean, are you okay?_",0);
			add_dialog_choice(0,"Yeah...");
		}
		bmessage = run_dialog(1);

		if(get_flag(60,0) >= 2){
			reset_dialog();
			add_dialog_str(0,"_They're not in the rest of these cells.  They were split up before you got here.  I thought you might have known, but now that I look back on it, you were knocked unconscious._",0);
			add_dialog_str(1,"_That well-dressed nephilim took you personally here...  I followed you, not the rest of your captors.  Sorry.  I don't know why they did that._",0);
		}
		else{
			reset_dialog();
			add_dialog_str(0,"_Well...  That's good to hear.  You were knocked unconscious somewhere along the way to this place.  Looks like you weren't too injured, though._",0);
			add_dialog_str(1,"_That nephil...  Ratbane XIV, he seems to be a wily one.  I'm not sure, but I think he noticed me.  The other nephils were completely oblivious, but that one...  He has a goal._",0);
		}
		add_dialog_str(2,"_Anyway, the first step is to get you out of here.  I don't have a key, but I know who does.  And you won't like this, but it's that Zenbu character._",0);
		add_dialog_str(3,"_Still, I should be able to nab it from him if I'm speedy enough...  I hope.  Or maybe I'll be able to find a spare.  Anyway, that's the situation.  Don't let them know I'm here, okay?",0);
		add_dialog_str(4,"Suddenly, Anthony turns his head and looks entirely aghast.",0);
		add_dialog_str(5,"_Oh...  Bloody hell._",0);
		add_dialog_choice(0,"What?");
		bmessage = run_dialog(1);

		set_character_facing(9,2);
		put_effect_on_char(9,12,1,2);
		force_instant_terrain_redraw();
		run_animation_sound(69);
		kill_char(9,2,0);
		pause(3);

		activate_hidden_group(2);
		relocate_character(10,19,16);
		force_instant_terrain_redraw();
		pause(15);

		reset_dialog();
		add_dialog_str(0,"Oh...  Bloody hell.",0);
		clear_buffer();
		append_string("_So...  ");
		append_char_name(0);
		append_string(".  We meet again- admittedly, in a far less advantageous situation for you.  I trust you have been thinking over what I have told you..._");
		get_buffer_text(custom_m);
		add_dialog_str(1,custom_m,0);
		if(get_flag(99,0) == 1){
			add_dialog_str(2,"...That bastard.  How does Zenbu know?",0);
			add_dialog_str(3,"_Her murderer is in this fortress.  Yes!  If you move quickly, you will be able to avenge her, and protect people at the same time.  How romantic.  But first, I need to let you out._",0);
			add_dialog_choice(0,"Who killed her?!");
			bmessage = run_dialog(1);
		}
		if(get_flag(99,0) == 2){
			add_dialog_str(2,"...That bastard.  How does Casimir know?",0);
			add_dialog_str(3,"_Sabertooth is in this fortress.  Sabertooth, the one who murdered your whole damned family!  He's here!  He wants you._",0);
			add_dialog_choice(0,"Who is Sabertooth?!");
			bmessage = run_dialog(1);
		}

		reset_dialog();
		if(get_flag(99,0) == 1)
			add_dialog_str(0,"_His name is Sabertooth.  Not even I know much about him.  He is a magician, and extremely good...  Powerful.  Terribly powerful._",0);
		if(get_flag(99,0) == 2)
			add_dialog_str(0,"_Not even I know much about Sabertooth.  He is a magician, and extremely good...  Powerful.  Terribly powerful._",0);
		if(party_size() == 1)
			add_dialog_str(1,"_He wants something with you.  Just you in particular.  For this, he made a few arrangements...  General Foottracer, who to this date remains influential in Imperial politics, is involved.  We have spoken on multiple occasions._",0);
		if(party_size() == 2)
			add_dialog_str(1,"_He wants something with you.  Not your partner.  For this, he made a few arrangements...  General Foottracer, who to this date remains influential in Imperial politics, is involved.  We have spoken on multiple occasions._",0);
		if(party_size() > 2)
			add_dialog_str(1,"_He wants something with you.  Not your partners.  For this, he made a few arrangements...  General Foottracer, who to this date remains influential in Imperial politics, is involved.  We have spoken on multiple occasions._",0);
		add_dialog_str(2,"_I am not at liberty to tell you the details of the plan, but it is going to be the source of great tragedy.  These nephils...  All of them here will die._",0);
		if(get_flag(99,0) == 1)
			add_dialog_str(3,"Zenbu looks over you briefly.  _Surprised?  Do not be.  This plot is one that is greater than the both of us.  Which is why I am going to release you._",0);
		if(get_flag(99,0) == 2)
			add_dialog_str(3,"Casimir looks over you briefly.  _You look strangely pleased.  Are you sure that you understand the ramifications?  This plot is one that is greater than the both of us.  Which is why I am going to release you._",0);
		add_dialog_str(4,"_My master beckons.  Climb towards my master and I, and we two will be able to exact revenge.  Please...  Join me, friend._",0);
		add_dialog_choice(0,"...");
		bmessage = run_dialog(1);
		if(get_flag(24,0) == 0)
			set_flag(24,0,1);

		set_terrain(20,17,30);
		force_instant_terrain_redraw();
		play_sound(99);
		pause(5);

		erase_char(10);
		put_boom_on_space(19,16,2,0);
		force_instant_terrain_redraw();
		run_animation_sound(10);

		if(get_flag(99,0) == 1)
			message_dialog("So...  Zenbu has let you out.  Is this your chance?  This corridor seems to be fairly quiet.  Lucky break.","Time to protect your friends.");
		if(get_flag(99,0) == 2)
			message_dialog("So...  Casimir has let you out.  Is this your chance?  This corridor seems to be fairly quiet.  Lucky break.","Time to cause some serious havoc.");

		set_flag(61,0,21);
		block_entry(1);
	}

	if(get_flag(61,0) < 20){
		inc_flag(61,0,1);
	}

	if(get_flag(64,0) > 0){
		inc_flag(64,0,-1);
		if(get_flag(64,0) == 0){
			put_effect_on_space(22,24,10,4,1);
			run_animation_sound(43);
		}
	}
	if(get_flag(65,0) > 0){
		inc_flag(65,0,-1);
		if(get_flag(65,0) == 0){
			put_effect_on_space(26,24,10,4,1);
			run_animation_sound(43);
		}
	}
	if(get_flag(66,0) > 0){
		inc_flag(66,0,-1);
		if(get_flag(66,0) == 0){
			put_effect_on_space(26,28,10,4,1);
			run_animation_sound(43);
		}
	}
	if(get_flag(67,0) > 0){
		inc_flag(67,0,-1);
		if(get_flag(67,0) == 0){
			put_effect_on_space(22,28,10,4,1);
			run_animation_sound(43);
		}
	}

break;

beginstate 10;

	if(get_flag(26,0) < 45){
		message_dialog("This fortress is indeed of Imperial artisanship.  Bizarrely enough, not even the crowns and banners have been dismantled.  Was that actually ordered?","More importantly, there are no nephils around.  You don't seem to be threatened for the moment.");
		set_flag(26,0,45);
	}

break;

beginstate 11;

	if(get_flag(62,0) == 0){
		if(get_flag(99,0) == 1)
			message_dialog("Perhaps this was Zenbu's doing, but these doors are solidly locked.  Nobody will be going in or out of this area.","Considering how quickly you would be stormed if your presence was announced, this must be more than a coincidence.");
		if(get_flag(99,0) == 2)
			message_dialog("Perhaps this was Casimir's doing, but these doors are solidly locked.  Nobody will be going in or out of this area.","Considering how quickly you would be stormed if your presence was announced, this must be more than a coincidence.");
		set_flag(62,0,1);
	}

break;

beginstate 12;

	if(get_flag(26,0) < 46){
		if(is_combat() == 1){
			block_entry(1);
			end();
		}

		activate_hidden_group(3);

		if(get_flag(99,0) == 1)
			message_dialog("Up ahead, you see...","No.  It can't be, can it?  Oh, but what a pleasing illusion...");
		if(get_flag(99,0) == 2)
			message_dialog("Up ahead, you see...","What a cruel illusion.  It can't be her.  It isn't her.  What bizarre torture.");

		set_character_facing(0,4);
		rcty = 21;
		while(rcty <= 25){
			relocate_character(0,8,rcty);
			force_view_center(8,rcty);
			force_instant_terrain_redraw();
			pause(3);

			rcty = (rcty + 1);
		}

		pause(4);
		reset_dialog();
		add_dialog_str(0,"It...  Looks just like her.  It really does.  But it can't be her.  It looks too...  Fake.  Mechanical.  It is a twisted simulacrum at best.",0);
		add_dialog_str(1,"_Look...  Be-be-be-behold your precious...  Is this not what you...  Wanted?  Wanted?  Yes._",0);
		add_dialog_str(2,"_Love you, love you, love you!_",40);
		add_dialog_str(3,"_See...  You, family, love...  Sister.  Yours.  L-l-l-love...  Her favorites..._",20);
		add_dialog_str(4,"...",0);
		add_dialog_str(5,"Its voice.  It sounds like her, but it is stunted and stifled.  Its voice crackles and repeats.  It is a shamshod device that speaks to a perversion of your past.",0);
		add_dialog_choice(0,"Damn you, Sabertooth!");
		bmessage = run_dialog(1);

		set_character_pose(11,2);
		put_boom_on_char(11,4,0);
		force_instant_terrain_redraw();
		run_animation_sound(54);
		pause(5);

		reset_dialog();
		clear_buffer();
		append_string("_How does it feel, ");
		append_char_name(0);
		append_string("?  Do you not love me?_");
		get_buffer_text(custom_m);
		add_dialog_str(0,custom_m,0);
		add_dialog_str(1,"It speaks with a different voice now- it is tigrish and coarse.  It is deep, rumbling, and stifled like your sister's was before.  What...  is it?",0);
		add_dialog_str(2,"Besides that, there is now violent looking energy surging all over your sister's skin.  She now appears to be lethal.",0);
		add_dialog_str(3,"_I am waiting for you...  Get past her...  If you can?  Or embrace her, and let the kinetic backlash of her embrace send you towards her in the pits of Hell!  Fight, little human!  Amuse me before I win._",0);
		add_dialog_choice(0,"Sabertooth!");
		bmessage = run_dialog(1);

		activate_hidden_group(10);
		rcty = 21;
		while(rcty <= 24){
			set_terrain(5,rcty,290);
			set_terrain(6,rcty,0);
			rcty = (rcty + 1);
		}
		force_instant_terrain_redraw();
		play_sound(99);
		pause(8);
		play_sound(10);

		message_dialog("Suddenly, a large number of nephilim appear out of their invisibility spell behind you.  A large group is standing to the west of you in a hidden alcove and you have the glowing replica of your sister to deal with.","...Bloody hell.  This is not your day.");

		block_entry(1);
		set_flag(26,0,46);
	}

break;

beginstate 13;

	if(get_flag(26,0) < 47){
		message_dialog("This is indeed the largest building of the Nephil Fortress.  It has to be- you can see all of the walls from here, all of the barracks, all of the longhouses, and all of the bonfires.  The same ones you saw at the watchtower with Malachai...","It's nighttime.  This is fortunate for you, since this place is not being guarded.  You will be able to get your business here done quickly, and hopefully be able to leave the way Anthony came in.");
		set_flag(26,0,47);
	}

break;

beginstate 14;

	if(get_flag(64,0) == 0 && get_flag(26,0) < 49){
		put_boom_on_char(0,1,0);
		run_animation_sound(5);
		damage_char(0,100,4);
	}

break;

beginstate 15;

	if(get_flag(65,0) == 0 && get_flag(26,0) < 49){
		put_boom_on_char(0,1,0);
		run_animation_sound(5);
		damage_char(0,100,4);
	}

break;

beginstate 16;

	if(get_flag(66,0) == 0 && get_flag(26,0) < 49){
		put_boom_on_char(0,1,0);
		run_animation_sound(5);
		damage_char(0,100,4);
	}

break;

beginstate 17;

	if(get_flag(67,0) == 0 && get_flag(26,0) < 49){
		put_boom_on_char(0,1,0);
		run_animation_sound(5);
		damage_char(0,100,4);
	}

break;

beginstate 18;

	if(get_flag(26,0) < 49){
		set_flag(64,0,2);
		put_effect_on_space(22,24,10,4,1);
		run_animation_sound(43);
	}

break;

beginstate 19;

	if(get_flag(26,0) < 49){
		set_flag(65,0,2);
		put_effect_on_space(26,24,10,4,1);
		run_animation_sound(43);
	}

break;

beginstate 20;

	if(get_flag(26,0) < 49){
		set_flag(66,0,2);
		put_effect_on_space(26,28,10,4,1);
		run_animation_sound(43);
	}

break;

beginstate 21;

	if(get_flag(26,0) < 49){
		set_flag(67,0,2);
		put_effect_on_space(22,28,10,4,1);
		run_animation_sound(43);
	}

break;

beginstate 22;

	message_dialog("These gates are, thank goodness, closed.  If they were open, well, the company you would be amongst would be far from benign.","");

break;

beginstate 23;

	if(get_flag(26,0) < 48){
		march_party(24,31);
		force_view_center(24,31);
		force_instant_terrain_redraw();
		pause(4);

		set_terrain(23,32,26);
		set_terrain(24,32,26);
		set_terrain(25,32,26);
		force_instant_terrain_redraw();
		play_sound(99);
		pause(5);

		activate_hidden_group(4);
		put_boom_on_space(24,26,2,0);
		force_instant_terrain_redraw();
		run_animation_sound(10);

		reset_dialog();
		add_dialog_str(0,"This burly man has a very large axe and is armed to the teeth.  He is, put bluntly, enormous.  Also, he is likely very dangerous.",0);
		add_dialog_str(1,"_Fwuahahaha!  Behold, mere mortal, the visage of Luthair, Supreme Commander of the Nephil Armies!  You may have met Ratbane XIV, but he is merely a tool.  A figurehead.  What your unworthy eyes stare upon is the real deal._",0);
		add_dialog_str(2,"_I will not mince words.  You die here at my hand.  Come, and behold the might and fury of a true god!_",0);
		bmessage = run_dialog(1);

		reset_dialog();
		add_dialog_str(0,"He seems ready to fight.  But something seems odd...  His armor is glistening in a way that reflects on magic more so than steel.  The three glowing pylons may have something to do with it.  There must be a trick somewhere.",0);
		add_dialog_str(1,"Furthermore, the stairs that lead down into the small area where he is standing have sparks running furiously across them.  They might be dangerous, or they might not be.  Who knows.  At any rate, you don't have the time to cogitate this.",0);
		add_dialog_str(2,"Time to fight.",0);
		bmessage = run_dialog(1);

		set_flag(26,0,48);
		block_entry(1);
	}

break;

beginstate 24;

	if(get_flag(26,0) < 49){
		reset_dialog();
		add_dialog_str(0,"There is a lever here.  It has three notches, going from left to right:",0);
		add_dialog_str(1,"Power Influx, Power Shield and Power Redux",0);
		add_dialog_str(2,"Which way do you pull the lever?",0);
		add_dialog_choice(0,"Left");
		add_dialog_choice(1,"Leave it be");
		add_dialog_choice(2,"Right");
		bmessage = run_dialog(1);

		if(bmessage == 2){
			block_entry(1);
			end();
		}
		if(bmessage == 1){
			set_terrain(24,24,137);
			booms = 0;
			while(booms <= 2){
				rctx = 22;
				while(rctx <= 26){
					rcty = 24;
					while(rcty <= 28){
put_boom_on_space(rctx,rcty,1,0);
						rcty = (rcty + 1);
					}
					rctx = (rctx + 1);
				}
				force_instant_terrain_redraw();
				run_animation_sound(5);

				booms = (booms + 1);
			}

			message_dialog("_Aaaaaugh!  No!  I am Duke Eubans...  It cannot end this way!_","");
			kill_char(8,2,0);
			damage_char(0,1000,4);

			if(char_ok(0) == FALSE){
				message_dialog("OUCH.  The pylons, in the last instant of your life, flood the area with power.  Neither you nor General Luthair last more than an instant.","But General Luthair...  Was Duke Eubans?");
				end_scenario(0);
				end();
			}

			message_dialog("You...  You're alive!!!  You actually managed to survive such incredibly brutal force.  That's incredible.","");

			set_terrain(29,25,31);
			set_terrain(29,26,31);
			set_terrain(29,27,31);
			force_instant_terrain_redraw();
			play_sound(99);
			pause(5);

			message_dialog("So...  Sabertooth was expecting you to defeat this stooge as well.  How convenient.","The gates are open to the east.  He must be waiting for you.");
		}

		if(bmessage == 3){

			erase_char(8);
			activate_hidden_group(11);
			relocate_character(13,24,27);
			put_boom_on_space(24,26,0,0);
			force_instant_terrain_redraw();
			run_animation_sound(5);
			pause(5);

			message_dialog("A small explosion erupts as the power flow surrounding Luthair stops.  Unfortunately, the general is able to avoid it just in time.","_Ah!  You think me but trash, but if it is close combat that you want, death you shall receive!  En garde!_");
			
		}

		set_flag(26,0,49);

	}

	else{
		message_dialog("This lever is no longer operational.","");
	}

break;

beginstate 25;

	if(get_flag(26,0) < 50){
		message_dialog("_Good...  Good!  Come.  I am waiting for you.  This kill will be especially rewarding!_","");
		set_flag(26,0,50);
	}

break;

beginstate 26;

	if(get_flag(26,0) < 51){
		message_dialog("...Impressive.  This seems to be a large throne room of sorts.  On top of it, though, you see two familiar figures.","Zenbu, and an old, childhood nightmare.");
		set_flag(26,0,51);
	}

break;

beginstate 27;

	if(get_flag(26,0) < 52){
		set_terrain(32,20,62);
		set_terrain(33,20,62);
		set_terrain(34,20,62);
		force_view_center(33,19);
		march_party(33,19);
		force_instant_terrain_redraw();
		play_sound(99);
		pause(5);

		set_flag(26,0,52);
	}

break;

beginstate 28;

	if(get_flag(26,0) < 53){
		if(is_combat() == TRUE){
			block_entry(1);
			end();
		}

		march_party(33,18);
		force_view_center(33,18);
		force_instant_terrain_redraw();
		pause(7);

		clear_buffer();
		append_string("_Oh, but I cannot see the nuances of your supple visage from here...  Come closer.  Come to me, ");
		append_char_name(0);
		append_string("!");
		get_buffer_text(custom_m);
		message_dialog("_Welcome...  Welcome, to the room from whence General Foottracer planned to begin his coup d'etat.  Welcome, to the room where Ratbane XIII was doomed to defeat.  Welcome, to the room where Ratbane XIV is doomed to defeat._",custom_m);

		relocate_character(0,33,12);
		set_character_pose(6,1);
		force_view_center(33,12);
		put_boom_on_space(33,12,2,0);
		force_instant_terrain_redraw();
		run_animation_sound(10);
		pause(4);

		set_character_pose(6,0);
		force_instant_terrain_redraw();
		pause(4);

		reset_dialog();
		add_dialog_str(0,"_So...  How does it feel, to face your murderer like this?  I must admit, few creatures ever have the luxury of knowing precisely when they will die.  I am somewhat envious._",0);
		if(get_flag(99,0) == 1){

			add_dialog_choice(0,"Why?  Why did you do it?");
			bmessage = run_dialog(1);

			reset_dialog();
			add_dialog_str(0,"_Why?  Because you have the genes of many good men.  I had made a living watching your kind suffer.  Your altruistic deeds, staring threats with kindness and being cut down._",0);
			add_dialog_str(1,"_A staunch, well-trained animal like yourself will never understand the absolute rush of breaking a frail neck between your clenched fists...  You will never know how to truly drain away innocent life._",0);
			add_dialog_str(2,"_Immortals like me, we are needed.  And yet, your ancestors...  You murdered so many truly worthy sorcerers and torturers.  That is why I exact my revenge._",0);
			add_dialog_choice(0,"They deserved it!");
			bmessage = run_dialog(1);

			reset_dialog();
			add_dialog_str(0,"_I must admit, you are a pesky one.  I had planned to bribe the guards into arresting you to torture at my leisure...  Your escape was not foreseen._",0);
			add_dialog_str(1,"_That is why I came here.  These nephils will die for my pleasure, but you are my real prize!  You are the gored summit of my mountain of carnage!_",0);
			add_dialog_choice(0,"I will put you down! Sabertooth!");
			bmessage = run_dialog(1);

		}

		if(get_flag(99,0) == 2){

			add_dialog_choice(0,"I genuinely don't care.");
			bmessage = run_dialog(1);

			reset_dialog();
			add_dialog_str(0,"_You mean to say, you don't care about how I singlehandedly butchered your family?  Sachiko!  Aaron!  Chika!  All three of them, destroyed._",0);
			add_dialog_str(1,"_And this rebellion?  Manufactured!  Oh, I will so enjoy seeing these furballs being wiped off of the face of the planet.  You will watch from hell, and perhaps then, if you are truly wise, you may laugh!_",0);
			add_dialog_choice(0,"I've heard enough.");
			bmessage = run_dialog(1);

			reset_dialog();
			add_dialog_str(0,"_Have you?  Or would you like to hear about all of the things I did in my lifetime?  Would that stir up your rage?  What if I made more simulacra of your mother and father?  Could you cut those down as well?_",0);
			add_dialog_str(1,"_Be sad!  Be miserable!  And then burn in hell eternally.  You are nothing but a wasted knight, a paladin of folly, and a pathetic mortal!  Feel honored to behold me!  I shall win!_",0);
			add_dialog_choice(0,"(Attack.)");
			bmessage = run_dialog(1);

		}

		relocate_character(7,34,9);
		set_character_pose(7,1);
		set_character_pose(6,11);
		set_character_facing(7,2);
		put_effect_on_space(33,9,12,1,2);
		force_instant_terrain_redraw();
		run_animation_sound(69);
		pause(4);

		reset_dialog();
		add_dialog_str(0,"_Enough!  Burn in the hell you made for everyone in this valley of death!_",0);
		if(get_flag(99,0) == 1)
			add_dialog_choice(0,"Zenbu?");
		if(get_flag(99,0) == 2)
			add_dialog_choice(0,"Casimir?");
		bmessage = run_dialog(1);

		message_dialog("_Ngghhh...  Damn you, Zenbu!  I will be back some day!_","");
		erase_char(6);
		put_boom_on_space(33,9,2,0);
		force_instant_terrain_redraw();
		run_animation_sound(10);

		set_character_facing(7,4);
		set_character_pose(7,0);
		force_instant_terrain_redraw();
		pause(6);

		reset_dialog();
		clear_buffer();
		append_string("So, ");
		append_char_name(0);
		append_string(".  He fled, wounded.  But now, I have the army at my back!  His time will come eventually.  I trust that he is now a non-issue.");
		get_buffer_text(custom_m);
		add_dialog_str(0,custom_m,0);
		add_dialog_str(1,"_I like your attitude.  You have the makings of a true warrior on the inside.  Yes, we could get along well...  You and me.  Us two.  Together._",0);
		add_dialog_str(2,"_You have had much time to think.  You must know that it is true.  We are the same.  Both of us, tortured...  Brought into something terrible.  But now that he is injured, are we both not beyond that?_",0);
		add_dialog_str(3,"_We are.  We are something greater.  Something far more powerful.  Can you not see it?  Our future!  Brothers in hatred._",0);
		if(get_flag(99,0) == 1){
			add_dialog_choice(0,"Hate only brings destruction.");
			bmessage = run_dialog(1);

			reset_dialog();
			add_dialog_str(0,"_What?  What did you say?  Hate brings destruction?  Well, of course!  It has, does, and will continue to do so.  But we can ride this despicable steed, rather than be trampled by it._",0);
			add_dialog_str(1,"_An army of nephilim is at my back.  I can take command!  I can defeat all opponents.  But you don't understand this, do you?  You don't understand my ambition!_",0);
			add_dialog_choice(0,"What are you talking about?");
			bmessage = run_dialog(1);
		}
		if(get_flag(99,0) == 2){
			add_dialog_choice(0,"Sorry, I don't have the time to waste here.");
			bmessage = run_dialog(1);

			reset_dialog();
			add_dialog_str(0,"_What?  What did you say?  No time to waste?  You fool!  This power, this accomplishment...  You are turning down something so extraordinary, you may never have a greater chance!_",0);
			add_dialog_str(1,"_This is a game you win.  And together, we could do it!  We have the possibility.  I am the master of this realm.  I will win this vile game of life and violence for sure!_",0);
			add_dialog_choice(0,"You do that.");
			bmessage = run_dialog(1);
		}

		pause(4);
		play_sound(95);
		pause(4);

		reset_dialog();
		add_dialog_str(0,"_You...  Casimir...  How dare you strike me!_",0);
		if(get_flag(99,0) == 2)
			add_dialog_str(1,"It is Sabertooth.  He does not sound pleased.",0);
		if(get_flag(99,0) == 1)
			add_dialog_str(1,"It is Sabertooth.  He does not sound pleased...  But Casimir- is that Zenbu?",0);
		add_dialog_str(2,"_I may be severely injured by your treachery, but do not forget that I control your body!  Do not forget, as I make you slay your compatriot and conspirator!_",0);
		add_dialog_str(3,"Zenbu, Casimir, raises his claws into the air.  His eyes are bloodshot, and his motions are mechanical.  Indeed, his body does not appear to be his anymore.  This could be very bad.",0);
		add_dialog_choice(0,"Casimir...");
		bmessage = run_dialog(1);

		set_character_pose(7,2);
		force_instant_terrain_redraw();
		play_sound(18);
		pause(10);

		set_character_pose(7,1);
		put_effect_on_space(34,9,12,1,2);
		force_instant_terrain_redraw();
		run_animation_sound(69);
		pause(5);

		reset_dialog();
		add_dialog_str(0,"Wh...  What?  Casimir!  Did he just slay himself?",0);
		add_dialog_str(1,"The red in his eyes retreats, as his limbs loosen up again.  He lets out a small grin.",0);
		add_dialog_str(2,"_You...  You were right.  I can win this game...  I can be successful...  But I cannot be happy._",0);
		add_dialog_str(3,"_I have always wanted to...  escape?  No, to play by my own rules...  But never, did I ever try...  To be myself..._",0);
		add_dialog_str(4,"_Please.  Be yourself.  Be strong.  Carry...  This ambition of yours and mine.  Farewell._",0);
		add_dialog_str(5,"He expires.  Casimir is dead.",0);
		if(get_flag(99,0) == 1)
			add_dialog_choice(0,"That was truly noble.");
		if(get_flag(99,0) == 2)
			add_dialog_choice(0,"That wasn't what I meant, but...");
		bmessage = run_dialog(1);

		kill_char(7,2,0);
		pause(4);

		message_dialog("That...  Is that it?  You are safe.  Sabertooth has been mauled into an incapacitated state, and Zenbu...  Casimir is no more.","This is the end of your ethnocentric, authoritarian drama.  Time to find a way out of here and...  Live.");
		block_entry(1);
		set_flag(26,0,60);
	}

break;

beginstate 29;

	if(get_flag(26,0) < 61){

		reset_dialog();
		add_dialog_str(0,"This apparently controls some sort of portal in the other room.  There is a series of destinations you can set this portal to go to, but currently, the portal is not activated- hence why you did not see it before.",0);
		add_dialog_str(1,"There are many bases, but all of them go to places within nephilim-held territory.  There's only one destination on here that looks like a place you'd go to...",0);
		add_dialog_choice(0,"Fort Ivalice");
		bmessage = run_dialog(0);
		play_sound(9);
		play_sound(10);
		set_terrain(33,10,268);
		set_flag(26,0,61);

		message_dialog("That's it...  Time to move on.","");

	}
	else{
		message_dialog("The destination has been set.  You have no more business here.","");
	}

break;

beginstate 30;

	if(get_flag(26,0) >= 61){
		reset_dialog_preset_options(3);
		bmessage = run_dialog(0);
		if(bmessage == 1){
			block_entry(1);
			end();
		}

		play_sound(10);
		set_flag(44,0,1);
		set_flag(45,0,0);
		set_flag(46,0,0);
		set_flag(47,0,0);
		set_flag(48,0,0);
		set_flag(49,0,0);
		set_flag(50,0,0);
		move_to_new_town(7,42,32);
	}

break;

